使用MDI介面時，有時候需要在MDI客戶視窗中顯示一些圖形或軟體封面，使得軟體介面不會顯得空曠，軟體功能也能一目了然。然而在Delphi中並沒有直接給出這些介面。在MDI窗體中放入任何圖形控制項在執行時都不能顯示。因此需要對MDI窗體進行改造。
申明：
本方案僅針對MDI窗體，如果應用在非MDI窗體中，後果難說，你自已試試吧。
記住，窗體的FormStyle屬性要設定為：fsMDIForm。
解決方案：
1.在MDI主窗體中無法接收到MDI客戶視窗的訊息（Message），因此，需要自已定義客戶視窗的處理過程（Window PRocedure），並接管MDI客戶視窗（需在重載的CreateWnd過程中實現）：
procedure TMDIForm.CreateWnd;
begin
inherited;
FNewWndProc := MakeObjectInstance(ClientWndProc);
FOldWndProc := Pointer(GetWindowLong(ClientHandle, GWL_WNDPROC));
SetWindowLong(ClientHandle, GWL_WNDPROC, Longint(FNewWndProc));
end;
其中，ClientWndProc為自訂的視窗過程： procedure ClientWndProc(var Message: TMessage);
FOldWndProc用來存放舊的視窗過程的指標。
2.實現自已的客戶視窗過程：
procedure TMDIForm.ClientWndProc(var Message: TMessage);
var
R: TRECT;
procedure Default;
begin
with Message do
Result := CallWindowProc(FOldWndProc, ClientHandle, Msg, wParam, lParam);
end;
var
PS: TPaintStruct;
begin
R := ClientRect;
case Message.Msg of
WM_PAINT:
begin
BeginPaint(ClientHandle,PS);
try
Canvas.Lock;
try
Canvas.Handle := PS.hdc;
try
Paint;
if ControlCount > 0 then
PaintControls(PS.hdc,Controls[0]);
finally
Canvas.Handle := 0;
end;
finally
Canvas.Unlock;
end;
finally
EndPaint(ClientHandle,PS);
end;
end;
WM_ERASEBKGND:
begin
DrawBG(TWMEraseBkGnd(Message).DC);
Message.Result := 1;
end;
WM_VSCROLL,WM_HSCROLL:
begin
InvalidateRect(ClientHandle,@R,true);
Default;
end;
WM_SIZE:
begin
InvalidateRect(ClientHandle,@R,true);
Default;
end;
else
Default;
end;
end;
上面的DrawBG是用來畫窗背景的。
3.實現視窗背景。
為了可以讓繼承者也能定義自已的背景，故此流程說明為virtual：
protected
procedure DrawBG(DC: HDC); virtual;
在此，DrawBG過程只是簡單的填充視窗背景：
procedure TMDIForm.DrawBG(DC: HDC);
begin
if Brush.Color <> clNone then
FillRect(DC, ClientRect, Brush.Handle);
end;
4.綜上所述，總結TMDIFrom類別定義如下：
TMDIForm = class(TForm)
private
FOldWndProc: TFarProc;
FNewWndProc: TFarProc;
procedure ClientWndProc(var Message: TMessage);
protected
procedure DrawBG(DC: HDC);virtual;
procedure CreateWnd; override;
end;
5.經過以上改造後，就可以在DrawBG中畫出指定的背景（需直接呼叫Windows 的GUI接口），或者直接使用圖形控件，或者實現窗體的OnPaint事件，MDI窗口從此多姿多彩。