在我們編寫使用者驗證程式中，很容易用ASP呼叫SQL語句來擷取資料表中是否有條件相符的記錄，然後再用ASP進行相關處理。
條條道路通羅馬！當然，我們也可以用SQL SERVER資料庫的預存程序來輕鬆實現這個功能。雖然相對而言較複雜，但其效率的提升是很明顯的，因為預存程序是在資料庫中已經編譯好的一段程序，我們只需用ASP將其所使用的各種參數正確傳遞就行了。
本文也主要是想透過一個簡單的例子，向大家介紹如何在ASP中呼叫帶參數的預存程序。希望大家能從中得到更多的啟蒙。
第一步，建立資料表userinfo
id int(4) not null,
fullname varchar(50) not null,
password varchar(20) not null,
nikename varchar(50) not null
第二步，建立預存程序usercheck
CREATE procedure usercheck
@infullname varchar(50),
@inpassword varchar(50),
@outcheck char(3) OUTPUT
as
if exists(select * from userinfo where fullname=@infullname and password=@inpassword )
select @outcheck='yes'
else
select @outcheck='no'
註：這裡建立了一個有三個參數的預存過程，第一個參數@infullname，這是個輸入參數，（使用者名稱）；第二個參數@inpassword，也是輸入參數， （密碼）；第三個參數@outcheck，這是個輸出參數，（是否存在此使用者），當定義輸出參數時在資料類型後必須加上"OUTPUT"，字樣。
然後，我們帶上前兩個輸入參數在SQL語句中檢索是否有符合條件的用戶，如果存在，輸出參數的值為"yes",否則為"no"。
第三步，編寫ASP程序，呼叫預存程序
<%
'表單提交標誌
if request("ok")=1 then
'建立資料庫連接
Set Comm=Server.CreateObject("ADODB.Command")
Comm.ActiveConnection="DSN=localserver;UID=sa;PWD=;Database=chaiwei"
'以comm物件建立預存程序連線,4代表連線類型為預存程序
Comm.CommandText="usercheck"
Comm.CommandType=4
'以p1為名稱建立comm物件的parameter方法。將第一個參數fullname追加到p1集合中'fullname 呼叫的第一個參數的名稱'200 參數類型varchar型'1 參數流向輸入，輸入為1,輸出為2
'50 參數的長度50
'request("fullname") 賦參數出始值
Set p1=Comm.CreateParameter("fullname",200,1,50,request("fullname"))
Comm.Parameters.Append p1
'以p1為名稱建立comm物件的parameter方法。將第二個參數password追加到p1集合中
'具體同上
Set p1=Comm.CreateParameter("password",200,1,20,request("password"))
Comm.Parameters.Append p1
'以p1為名稱建立comm物件的parameter方法。將第三個參數check追加到p1集合中
'129 參數型別char型
'2 參數流向輸出
'3 參數長度3
Set p1=Comm.CreateParameter("check",129,2,3)
Comm.Parameters.Append p1
'運行存儲過程
Comm.Execute
'提出結果，進行處理
if comm("check")="yes" then
response.write "歡迎進入系統！使用者名稱：" & comm("fullname") & " 密碼：" & comm("password")
else
response.write "對不起，您尚未註冊！"
end if
'釋放連接
Set Comm=nothing
else
'表單部份
%>