NeoGPT Recommender

NeoGPT-ผู้แนะนำ

แนวคิดเบื้องหลังพื้นที่เก็บข้อมูลนี้คือการสร้างแชทบอทที่รับรู้บริบทซึ่งสามารถอ่านและอัปเดตฐานข้อมูล Neo4j ได้ Cypher สร้างขึ้นโดยใช้ตำแหน่งข้อมูล GPT-4 ในขณะที่คำตอบถูกสร้างขึ้นด้วยโมเดล gpt-3.5-turbo โดยอิงตามข้อมูลจากฐานข้อมูล

เรียนรู้เพิ่มเติม: https://medium.com/neo4j/context-aware-knowledge-graph-chatbot-with-gpt-4-and-neo4j-d3a99e8ae21e

ฐานข้อมูล Neo4j

โปรเจ็กต์นี้ใช้โปรเจ็กต์คำแนะนำที่พร้อมใช้งานเป็นส่วนหนึ่งของ Neo4j Sandbox หากคุณต้องการอินสแตนซ์ภายในเครื่องของ Neo4j คุณสามารถกู้คืนดัมพ์ฐานข้อมูลได้ที่นี่

ตัวแปรสภาพแวดล้อม

ตรวจสอบให้แน่ใจว่าเติมตัวแปรสภาพแวดล้อมตามที่แสดงในไฟล์ .env.example

เริ่มโครงการ

ดำเนินโครงการโดยใช้

 docker-compose up

จากนั้นเปิดที่อยู่ localhost:8501 ในเบราว์เซอร์ที่คุณชื่นชอบ

ตัวอย่างการฝึกอบรมในส่วนของ english2cypher

คุณสามารถใช้ตัวอย่างต่อไปนี้เพื่อทำความเข้าใจว่าแชทบอตนี้มีความสามารถอะไร

 # I don't like comedy
MATCH (u:User {id: $userId}), (g:Genre {name:"Comedy"})
MERGE (u)-[:DISLIKE_GENRE]->(g)
RETURN distinct {answer: 'noted'} AS result
# I like comedy
MATCH (u:User {id: $userId}), (g:Genre {name:"Comedy"})
MERGE (u)-[:LIKE_GENRE]->(g)
RETURN distinct {answer: 'noted'} AS result
# I have already watched Top Gun
MATCH (u:User {id: $userId}), (m:Movie {title:"Top Gun"})
MERGE (u)-[:WATCHED]->(m)
RETURN distinct {answer: 'noted'} AS result
# I like Top Gun
MATCH (u:User {id: $userId}), (m:Movie {title:"Top Gun"})
MERGE (u)-[:LIKE_MOVIE]->(m)
RETURN distinct {answer: 'noted'} AS result
# What is a good comedy?
MATCH (u:User {id:$userId}), (m:Movie)-[:IN_GENRE]->(:Genre {name:"Comedy"})
WHERE NOT EXISTS {(u)-[:WATCHED]->(m)}
RETURN {movie: m.title} AS result
ORDER BY m.imdbRating DESC LIMIT 1
# Who played in Top Gun?
MATCH (m:Movie)<-[:ACTED_IN]-(a)
RETURN {actor: a.name} AS result
# What is the plot of the Copycat movie?
MATCH (m:Movie {title: "Copycat"})
RETURN {plot: m.plot} AS result
# Did Luis Guzmán appear in any other movies?
MATCH (p:Person {name:"Luis Guzmán"})-[:ACTED_IN]->(movie)
RETURN {movie: movie.title} AS result
# Do you know of any matrix movies?
MATCH (m:Movie)
WHERE toLower(m.title) CONTAINS toLower("matrix")
RETURN {movie:m.title} AS result
# Which movies do I like?
MATCH (u:User {id: $userId})-[:LIKE_MOVIE]->(m:Movie)
RETURN {movie:m.title} AS result
# Recommend a movie
MATCH (u:User {id: $userId})-[:LIKE_MOVIE]->(m:Movie)
MATCH (m)<-[r1:RATED]-()-[r2:RATED]->(otherMovie)
WHERE r1.rating > 3 AND r2.rating > 3 AND NOT EXISTS {(u)-[:WATCHED|LIKE_MOVIE|DISLIKE_MOVIE]->(otherMovie)}
WITH otherMovie, count(*) AS count
ORDER BY count DESC
LIMIT 1
RETURN {recommended_movie:otherMovie.title} AS result